Module: `platform`

Terraform module to provision Datadog resources.

The module consists of the following submodules:

monitors - to provision Datadog monitors
synthetics - to provision Datadog synthetics
permissions - to look up all available Datadog permissions
roles - to provision Datadog roles
slo - to provision Datadog Service Level Objectives
child_organization - to provision Datadog child organizations
organization_settings - to manage Datadog organization's settings

Notes on Datadog child organizations:

Users can be added to the parent-organization and/or multiple child-organizations and switch between them from the user account settings menu
The parent-organization can view the usage of individual child-organizations, allowing them to track trends in usage
The Multi-organization account feature is not enabled by default. Contact Datadog support to have it enabled
Free and Trial organizations cannot enable SAML
We can only create Datadog child organizations with terraform, but cannot destroy them. When trying to destroy, the following error is thrown:
```
  Warning: Cannot delete organization.

  Remove organization by contacting support (https://docs.datadoghq.com/help).
```

Introduction

Datadog resources (monitors, roles, etc.) are defined as catalog of YAML configuration files.

We maintain a comprehensive catalog of Datadog resources and welcome contributions via pull request!

The examples/complete in this module uses the catalog to provision the monitors on Datadog.

The examples/synthetics shows how to provision synthetic tests on Datadog for monitoring. Consult the synthetics README module for more details.

The examples/rbac shows how to use custom RBAC to provision Datadog roles with permissions and assign roles to monitors.

The examples/slo shows how to provision Service Level Objectives on Datadog for SLO monitoring.

The examples/child_organization shows how to provision Datadog child organizations.

The examples/organization_settings shows how to provision Datadog organization settings.

Usage

Provision Datadog monitors from the catalog of YAML definitions:

module "monitor_configs" {
  source  = "cloudposse/config/yaml"
  version = "1.0.2"

  map_config_local_base_path = path.module
  map_config_paths           = var.monitor_paths

  context = module.this.context
}

module "datadog_monitors" {
  source = "cloudposse/platform/datadog//modules/monitors"
  # version = "x.x.x"

  datadog_monitors     = module.monitor_configs.map_configs
  alert_tags           = var.alert_tags
  alert_tags_separator = var.alert_tags_separator

  context = module.this.context
}

Provision Datadog synthetics:

locals {
  synthetics_files = flatten([for p in var.synthetic_paths : fileset(path.module, p)])
  synthetics_list  = [for f in local.synthetics_files : yamldecode(file(f))]
  synthetics_map   = merge(local.synthetics_list...)
}

module "datadog_synthetics" {
  source = "cloudposse/platform/datadog//modules/synthetics"
  # version = "x.x.x"

  datadog_synthetics   = local.synthetics_map
  alert_tags           = var.alert_tags
  alert_tags_separator = var.alert_tags_separator

  context = module.this.context
}

Provision Datadog monitors, Datadog roles with defined permissions, and assign roles to monitors:

module "monitor_configs" {
  source  = "cloudposse/config/yaml"
  version = "1.0.2"

  map_config_local_base_path = path.module
  map_config_paths           = var.monitor_paths

  context = module.this.context
}

module "role_configs" {
  source  = "cloudposse/config/yaml"
  version = "1.0.2"

  map_config_local_base_path = path.module
  map_config_paths           = var.role_paths

  context = module.this.context
}

locals {
  monitors_write_role_name    = module.datadog_roles.datadog_roles["monitors-write"].name
  monitors_downtime_role_name = module.datadog_roles.datadog_roles["monitors-downtime"].name

  monitors_roles_map = {
    aurora-replica-lag              = [local.monitors_write_role_name, local.monitors_downtime_role_name]
    ec2-failed-status-check         = [local.monitors_write_role_name, local.monitors_downtime_role_name]
    redshift-health-status          = [local.monitors_downtime_role_name]
    k8s-deployment-replica-pod-down = [local.monitors_write_role_name]
  }
}

module "datadog_roles" {
  source = "cloudposse/platform/datadog//modules/roles"
  # version = "x.x.x"

  datadog_roles = module.role_configs.map_configs

  context = module.this.context
}

module "datadog_monitors" {
  source = "cloudposse/platform/datadog//modules/monitors"
  # version = "x.x.x"

  datadog_monitors     = module.monitor_configs.map_configs
  alert_tags           = var.alert_tags
  alert_tags_separator = var.alert_tags_separator
  restricted_roles_map = local.monitors_roles_map

  context = module.this.context
}

Provision a Datadog child organization:

module "datadog_child_organization" {
  source = "cloudposse/platform/datadog//modules/child_organization"
  # version = "x.x.x"

  organization_name                = "test"
  saml_enabled                     = false  # Note that Free and Trial organizations cannot enable SAML
  saml_autocreate_users_domains    = []
  saml_autocreate_users_enabled    = false
  saml_idp_initiated_login_enabled = true
  saml_strict_mode_enabled         = false
  private_widget_share             = false
  saml_autocreate_access_role      = "ro"

  context = module.this.context
}

Examples

Review the examples folder to see how to use the Datadog modules.

Also checkout our terraform-aws-components repository for more examples of how to use a mixture of modules to enhance monitors, slos, and synthetics with inheritence and templating!

Requirements

Name	Version
terraform	>= 1.0.0
datadog	>= 3.0.0

Providers

Name	Version
datadog	>= 3.0.0

Modules

Name	Source	Version
this	cloudposse/label/null	0.25.0

Resources

Name	Type
datadog_monitor.default	resource

Inputs

Name	Description	Type	Default	Required
additional_tag_map	Additional key-value pairs to add to each map in `tags_as_list_of_maps`. Not added to `tags` or `id`. This is for some rare cases where resources want additional configuration of tags and therefore take a list of maps with tag key, value, and additional configuration.	`map(string)`	`{}`	no
alert_tags	List of alert tags to add to all alert messages, e.g. `["@opsgenie"]` or `["@devops", "@opsgenie"]`	`list(string)`	`null`	no
alert_tags_separator	Separator for the alert tags. All strings from the `alert_tags` variable will be joined into one string using the separator and then added to the alert message	`string`	`"\n"`	no
attributes	ID element. Additional attributes (e.g. `workers` or `cluster`) to add to `id`, in the order they appear in the list. New attributes are appended to the end of the list. The elements of the list are joined by the `delimiter` and treated as a single ID element.	`list(string)`	`[]`	no
context	Single object for setting entire context at once. See description of individual variables for details. Leave string and numeric variables as `null` to use default value. Individual variable settings (non-null) override settings in context object, except for attributes, tags, and additional_tag_map, which are merged.	`any`	`{ "additional_tag_map": {}, "attributes": [], "delimiter": null, "descriptor_formats": {}, "enabled": true, "environment": null, "id_length_limit": null, "label_key_case": null, "label_order": [], "label_value_case": null, "labels_as_tags": [ "unset" ], "name": null, "namespace": null, "regex_replace_chars": null, "stage": null, "tags": {}, "tenant": null }`	no
datadog_monitors	Map of Datadog monitor configurations. See catalog for examples	`map(object({ name = string type = string message = string escalation_message = string query = string tags = list(string) notify_no_data = bool new_host_delay = number evaluation_delay = number no_data_timeframe = number renotify_interval = number notify_audit = bool timeout_h = number enable_logs_sample = bool include_tags = bool require_full_window = bool locked = bool force_delete = bool threshold_windows = map(any) thresholds = map(any) }))`	n/a	yes
delimiter	Delimiter to be used between ID elements. Defaults to `-` (hyphen). Set to `""` to use no delimiter at all.	`string`	`null`	no
descriptor_formats	Describe additional descriptors to be output in the `descriptors` output map. Map of maps. Keys are names of descriptors. Values are maps of the form `{<br/> format = string<br/> labels = list(string)<br/>}` (Type is `any` so the map values can later be enhanced to provide additional options.) `format` is a Terraform format string to be passed to the `format()` function. `labels` is a list of labels, in order, to pass to `format()` function. Label values will be normalized before being passed to `format()` so they will be identical to how they appear in `id`. Default is `{}` (`descriptors` output will be empty).	`any`	`{}`	no
enabled	Set to false to prevent the module from creating any resources	`bool`	`null`	no
environment	ID element. Usually used for region e.g. 'uw2', 'us-west-2', OR role 'prod', 'staging', 'dev', 'UAT'	`string`	`null`	no
id_length_limit	Limit `id` to this many characters (minimum 6). Set to `0` for unlimited length. Set to `null` for keep the existing setting, which defaults to `0`. Does not affect `id_full`.	`number`	`null`	no
label_key_case	Controls the letter case of the `tags` keys (label names) for tags generated by this module. Does not affect keys of tags passed in via the `tags` input. Possible values: `lower`, `title`, `upper`. Default value: `title`.	`string`	`null`	no
label_order	The order in which the labels (ID elements) appear in the `id`. Defaults to ["namespace", "environment", "stage", "name", "attributes"]. You can omit any of the 6 labels ("tenant" is the 6th), but at least one must be present.	`list(string)`	`null`	no
label_value_case	Controls the letter case of ID elements (labels) as included in `id`, set as tag values, and output by this module individually. Does not affect values of tags passed in via the `tags` input. Possible values: `lower`, `title`, `upper` and `none` (no transformation). Set this to `title` and set `delimiter` to `""` to yield Pascal Case IDs. Default value: `lower`.	`string`	`null`	no
labels_as_tags	Set of labels (ID elements) to include as tags in the `tags` output. Default is to include all labels. Tags with empty values will not be included in the `tags` output. Set to `[]` to suppress all generated tags. Notes: The value of the `name` tag, if included, will be the `id`, not the `name`. Unlike other `null-label` inputs, the initial setting of `labels_as_tags` cannot be changed in later chained modules. Attempts to change it will be silently ignored.	`set(string)`	`[ "default" ]`	no
name	ID element. Usually the component or solution name, e.g. 'app' or 'jenkins'. This is the only ID element not also included as a `tag`. The "name" tag is set to the full `id` string. There is no tag with the value of the `name` input.	`string`	`null`	no
namespace	ID element. Usually an abbreviation of your organization name, e.g. 'eg' or 'cp', to help ensure generated IDs are globally unique	`string`	`null`	no
regex_replace_chars	Terraform regular expression (regex) string. Characters matching the regex will be removed from the ID elements. If not set, `"/[^a-zA-Z0-9-]/"` is used to remove all characters other than hyphens, letters and digits.	`string`	`null`	no
restricted_roles_map	Map of monitors names to sets of Datadog roles to restrict access to each monitor	`map(set(string))`	`{}`	no
stage	ID element. Usually used to indicate role, e.g. 'prod', 'staging', 'source', 'build', 'test', 'deploy', 'release'	`string`	`null`	no
tags	Additional tags (e.g. `{'BusinessUnit': 'XYZ'}`). Neither the tag keys nor the tag values will be modified by this module.	`map(string)`	`{}`	no
tenant	ID element _(Rarely used, not included by default)_. A customer identifier, indicating who this instance of a resource is for	`string`	`null`	no

Outputs

Name	Description
datadog_monitor_ids	IDs of the created Datadog monitors
datadog_monitor_names	Names of the created Datadog monitors
datadog_monitors	Datadog monitor outputs

Module: platform

Introduction​

Usage​

Examples​

Requirements​

Providers​

Modules​

Resources​

Inputs​

Outputs​