Module: rds-cluster-instance-group

Terraform module to provision an RDS Aurora instance group for MySQL or Postgres along with a dedicated endpoint.

Use this module together with our terraform-aws-rds-cluster to provision pools of RDS instances. This is useful for creating reporting clusters that don't impact the production databases.

Supports Amazon Aurora Serverless.

Usage

Basic example

module "rds_cluster_replicas" {
  source             = "git::https://github.com/cloudposse/terraform-aws-rds-cluster-instance-group.git?ref=master"
  name               = "postgres"
  namespace          = "eg"
  stage              = "dev"
  attributes         = ["replicas"]
  cluster_identifier = "eg-dev-db"
  cluster_size       = "2"
  db_port            = "5432"
  instance_type      = "db.r4.large"
  vpc_id             = "vpc-xxxxxxxx"
  security_groups    = ["sg-xxxxxxxx"]
  subnets            = ["subnet-xxxxxxxx", "subnet-xxxxxxxx"]
  zone_id            = "Zxxxxxxxx"
}

With cluster parameters

module "rds_cluster_reporting" {
  source             = "git::https://github.com/cloudposse/terraform-aws-rds-cluster-instance-group.git?ref=master"
  cluster_size       = "2"
  namespace          = "eg"
  stage              = "dev"
  name               = "db"
  attributes         = ["reporting"]
  cluster_identifier = "eg-dev-db"
  instance_type      = "db.t2.small"
  vpc_id             = "vpc-xxxxxxx"
  security_groups    = ["sg-xxxxxxxx"]
  subnets            = ["subnet-xxxxxxxx", "subnet-xxxxxxxx"]
  zone_id            = "Zxxxxxxxx"

  cluster_parameters = [
    {
      name  = "character_set_client"
      value = "utf8"
    },
    {
      name  = "character_set_connection"
      value = "utf8"
    },
    {
      name  = "character_set_database"
      value = "utf8"
    },
    {
      name  = "character_set_results"
      value = "utf8"
    },
    {
      name  = "character_set_server"
      value = "utf8"
    },
    {
      name  = "collation_connection"
      value = "uft8_bin"
    },
    {
      name  = "collation_server"
      value = "uft8_bin"
    },
    {
      name         = "lower_case_table_names"
      value        = "1"
      apply_method = "pending-reboot"
    },
    {
      name         = "skip-character-set-client-handshake"
      value        = "1"
      apply_method = "pending-reboot"
    },
  ]
}

With enhanced monitoring

# create IAM role for monitoring
resource "aws_iam_role" "enhanced_monitoring" {
  name               = "rds-cluster-example-1"
  assume_role_policy = "${data.aws_iam_policy_document.enhanced_monitoring.json}"
}

# Attach Amazon's managed policy for RDS enhanced monitoring
resource "aws_iam_role_policy_attachment" "enhanced_monitoring" {
  role       = "${aws_iam_role.enhanced_monitoring.name}"
  policy_arn = "arn:aws:iam::aws:policy/service-role/AmazonRDSEnhancedMonitoringRole"
}

# allow rds to assume this role
data "aws_iam_policy_document" "enhanced_monitoring" {
  statement {
      actions = [
      "sts:AssumeRole",
    ]

    effect = "Allow"

    principals {
      type        = "Service"
      identifiers = ["monitoring.rds.amazonaws.com"]
    }
  }
}

module "rds_cluster_reporting" {
  source             = "git::https://github.com/cloudposse/terraform-aws-rds-cluster-instance-group.git?ref=master"
  cluster_size       = "2"
  namespace          = "eg"
  stage              = "dev"
  name               = "db"
  attributes         = ["reporting"]
  cluster_identifier = "eg-dev-db"
  db_port            = "5432"
  instance_type      = "db.r4.large"
  vpc_id             = "vpc-xxxxxxx"
  security_groups    = ["sg-xxxxxxxx"]
  subnets            = ["subnet-xxxxxxxx", "subnet-xxxxxxxx"]
  zone_id            = "Zxxxxxxxx"

  # enable monitoring every 30 seconds
  rds_monitoring_interval = "30"

  # reference iam role created above
  rds_monitoring_role_arn = "${aws_iam_role.enhanced_monitoring.arn}"
}